Amazon 数量限定タイムセール開催中

iMacros:EXTRACTで文字、HTML、画像を抜き出す【PART.5】

EXTRACTを使用して特定の文字、画像やHTMLを抜き出す

このページ【PART.5】でご説明するEXTRACT(エクストラック)は、使用頻度が非常に高いコマンドです。

WEB上の全てのデータ(文字、URL、HTML、画像など)を抜き出してPCに保存することができます。

それでは、実例を元に使い方をご紹介していきます。

ノーノちゃん

EXTRACT?なんか難しそう…
少し難しそうに見えますが、意味はそのままで「抜き出し」「抜き取る」「取り出す」というようなコマンドです。

テイくん

1. データを抜き出しやすいように設定変更

そのままの設定でも可能ですが、HTMLやCSSの知識が入ります。

あまり詳しくない方は変更しましょう。

1

設定画面を開く

imacros設定変更(EXTRACT)

2

レコーディング選択を開く

imacros設定変更(EXTRACT)

3

設定を変更

imacros設定変更(EXTRACT)
iMacrosに慣れるまでデータを抜き出す(EXTRACTを使う)時は上記の設定に変更しましょう。

ちなみにデフォルトは一番上の「Select the best record mode automatically」です。

4

設定を保存する

imacros設定変更(EXTRACT)

ノーノちゃん

設定を変更しない場合どうなるの?
コマンドを自動ではなく、手動で作成する項目が増えます。

テイくん

2. 特定データを抜き出してみよう

冒頭でもお伝えしましたが、EXTRACTは文字、URL、HTMLや画像を抜き出すために使用するコマンドです。

「抜き出すコマンド」「保存するコマンド」を必ずセットで使います。
※画像の場合のみ必要ありません。

まずは下記の表を確認してみてくださいね。

抜き出しコマンド 保存コマンド
文字 EXTRACT=TXT SAVEAS TYPE=EXTRACT FOLDER=*
URL EXTRACT=HREF
HTML EXTRACT=HTM
画像 CONTENT=EVENT:SAVEITEM 必要なし(抜き出すコマンドに含まれている)

それでは、各コマンドの使い方を順番にご説明していきます。

ノーノちゃん

たくさん色々なコマンドが出てきて、頭がパンクしそう(T_T)
もし解説読んでも分からなかったら、完成したマクロをそのまま貼り付けて動かしてみましょう。

テイくん

①文字(TXT)編

文字を抜き出す方法はEXTRACT=TXTを使います。

それと抜き出した後にデータを保存するコマンドSAVEAS TYPE=EXTRACT FOLDER=*が必須です。

サンプルマクロ
文字(TXT)【練習用サイト】のタイトルと本文を各10個づつ抜き出して保存する。

作業の流れ

STEP.1
マクロを作成
文字(TXT)【練習用サイト】の保存したい場所をクリックする。
STEP.2
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.3
マクロを再生
連続で複数回マクロを再生します。
STEP.4
データを確認
抜き出したデータがちゃんと保存されているか確認します。

※動画(約2分)を確認後、下の解説を読んで頂くと分かりやすいと思います。

【STEP.1】マクロを作成

1

文字(TXT)【練習用サイト】にアクセス

https://teilab-sub.net/?p=31

2

記憶を開始する

imacros-recored

3

抜き出したい場所をクリックする

EXTRACT TXT
※抜き出したい文字の周辺をクリックすれば大丈夫です。

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「EXTRACT_txt.iim」に変更しておきましょう。
マクロ名の変更
EXTRACT TXT


【STEP.2】マクロを編集

1

編集画面を開く

EXTRACT TXT
先ほど自動で作成されたマクロは以下のようになっています。

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=31
TAG POS=1 TYPE=H2 ATTR=*
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2
TAG POS=2 TYPE=H2 ATTR=*
TAG POS=2 TYPE=DIV ATTR=CLASS:sng-box<SP>box2

2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'1番から順番に1→2→3…と数値が増える
SET !LOOP 1

'吸い出す文字を確認しない設定(ポップアップをOFF)
SET !EXTRACT_TEST_POPUP NO

'文字(TXT)【練習用サイト】にアクセス
URL GOTO=https://teilab-sub.net/?p=31

'「タイトル」を抜き出す(h2)
TAG POS={{!LOOP}} TYPE=H2 ATTR=* EXTRACT=TXT

'「サンプルテキストです。」を抜き出す(本文)
TAG POS={{!LOOP}} TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=TXT

'吸い出したデータを「Downloadsフォルダ」に保存する
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*

【STEP.3】マクロを再生

1

作成したマクロをクリックする

2

Loop回数を変更する

タイトルと本文が10個分づつあるのでMax:10に変更します。
Max:10に変更


【STEP.4】データを確認

1

Downloadsフォルダを開く

Download

補足
Downloadsフォルダの場所がわからない場合は、iMacrosの保存先を変更の記事が参考になると思います。
2

抜き出したデータを開く

EXTRACT

以下のようになっていればOKです。
抜き出し後データ


②URL(HREF)編

URLを抜き出す方法はEXTRACT=HREFを使います。

こちらもEXTRACT=TXTと同じで、データを保存するコマンドSAVEAS TYPE=EXTRACT FOLDER=*が必須です。

サンプルマクロ
URL(HREF)【練習用サイト】のURLを10個抜き出して保存する。

作業の流れ

STEP.1
マクロを作成
URL(HREF)【練習用サイト】の保存したい場所をクリックする。
STEP.2
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.3
マクロを再生
連続で複数回マクロを再生します。
STEP.4
データを確認
抜き出したデータがちゃんと保存されているか確認します。

※動画(約4分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

URL(HREF)【練習用サイト】にアクセス

https://teilab-sub.net/?p=39

2

記憶を開始する

imacros-recored

3

抜き出したい場所をクリックする

EXTRACT HREF

ノーノちゃん

クリックするとリンク先に移動して、また戻らないといけないの?もし10個とかに増えたら面倒かも…
CTRLを押しながらクリックするとリンク先に移動しなくなります。覚えておきましょう(*^^*)

テイくん

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「EXTRACT_HREF.iim」に変更しておきましょう。
マクロ名の変更
EXTRACT HREF


【STEP.2】マクロを編集

1

編集画面を開く

EXTRACT HREF
先ほど自動で作成されたマクロは以下のようになっています。

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=39
TAG POS=1 TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/1
BACK
TAG POS=1 TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/2

2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'1番から順番に1→2→3…と数値が増える
SET !LOOP 1

'吸い出す文字を確認しない設定(ポップアップをOFF)
SET !EXTRACT_TEST_POPUP NO

'URL(HREF)【練習用サイト】にアクセス
URL GOTO=https://teilab-sub.net/?p=39
 
'※サンプルURLのリンク先を抜き出す 
TAG POS={{!LOOP}} TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/* EXTRACT=HREF

'吸い出したデータをダウンロードフォルダに保存する
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*

ノーノちゃん

「サンプルURLのリンク先を抜き出す」部分のhttps://teilab-sub.net/*の「*」米印みたいなマークはなんで入れたの?
これを入れないとURLを全て取得できません。詳しくは「4. 各コマンドの解説/*(ワイルドカード)」の所で説明しています。

テイくん


【STEP.3】マクロを再生

1

作成したマクロをクリックする

EXTRACT HREF

2

Loop回数を変更する

リンク先が10個あるのででMax:10に変更します。
Max:10に変更


【STEP.4】データを確認

1

Downloadsフォルダを開く

Download

2

抜き出したデータを開く

EXTRACT

以下のようになっていればOKです。
EXTRACT HREF


③HTML(HTM)編

HTMLを抜き出す方法はEXTRACT=HTMを使います。

このコマンドは、ほとんど使用することがありませんので詳しい解説は省略します。

先程作成した「文字」「URL」項目のマクロを変更したものを再生して、どんな感じになるのか確認するだけでOKです。

文字(TXT)

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
SET !LOOP 1
SET !EXTRACT_TEST_POPUP NO
URL GOTO=https://teilab-sub.net/?p=31
TAG POS={{!LOOP}} TYPE=H2 ATTR=* EXTRACT=HTM
TAG POS={{!LOOP}} TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=HTM
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
①文字(TXT)編のEXTRACT=TXTEXTRACT=HTMに変更したマクロです。

URL(HREF)

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
SET !LOOP 1
SET !EXTRACT_TEST_POPUP NO
URL GOTO=https://teilab-sub.net/?p=39
TAG POS={{!LOOP}} TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/* EXTRACT=HTM
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
②URL(HREF)編のEXTRACT=HREFEXTRACT=HTMに変更したマクロです。

④画像(SAVEITEM)編

画像を抜き出す方法はCONTENT=EVENT:SAVEITEMを使います。

こちらはEXTRACT=TXT(HREF)と違い保存するコマンドはいりません。

サンプルマクロ
画像(SAVEITEM)【練習用サイト】の画像を10個抜き出して保存する。

作業の流れ

STEP.1
マクロを作成
画像(SAVEITEM)【練習用サイト】の保存したい場所をクリックする。
STEP.2
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.3
マクロを再生
連続で複数回マクロを再生します。
STEP.4
データを確認
抜き出したデータがちゃんと保存されているか確認します。

※動画(約3分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

画像(SAVEITEM)【練習用サイト】にアクセス

https://teilab-sub.net/?p=59

2

記憶を開始する

imacros-recored

3

抜き出したい場所をクリックする

SAVEITEM

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「SAVEITEM.iim」に変更しておきましょう。
マクロ名の変更
SAVEITEM


【STEP.2】マクロを編集

1

編集画面を開く

SAVEITEM
先ほど自動で作成されたマクロは以下のようになっています。

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=59
TAG POS=1 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/2019/06/01.png
TAG POS=1 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/2019/06/02.png

2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'1番から順番に1→2→3…と数値が増える
SET !LOOP 1

'画像(SAVEITEM)【練習用サイト】にアクセス
URL GOTO=https://teilab-sub.net/?p=59

'画像を抜き出す
TAG POS={{!LOOP}} TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/*.png CONTENT=EVENT:SAVEITEM

【STEP.3】マクロを再生

1

作成したマクロをクリックする

SAVEITEM

2

Loop回数を変更する

画像が10個あるのでMax:10に変更します。
Max:10に変更


【STEP.4】データを確認

1

Downloadsフォルダを開く

Download

2

抜き出したデータを確認する

以下のようになっていればOKです。
SAVEITEM
※表示の仕方は設定によって違います。

3. 複数データを抜き出してみよう

先程は1個ずつ「文字」「URL」「画像」を抜き出しましたが、今度は一括で全てのデータを抜き出します。

項目が増えて難しく思えますが、いつもマクロは1行で1つの動作をします。

上から順番に見ていけば、どんなにマクロが長くなっても大丈夫です。

それでは「楽天の電子書籍ランキング」のページを使って解説していきます。

楽天ランキング編

抜き出しに使うコマンド以下の3つです。

  • EXTRACT=TXT(文字)
  • EXTRACT=HREF(URL)
  • CONTENT=EVENT:SAVEITEM(画像)
サンプルマクロ
楽天電子書籍ページの画像、タイトル、作者などを各30個抜き出して保存する。

作業の流れ

STEP.1
マクロを作成
楽天電子書籍ランキングのページで保存したい場所をクリックする。
CTRLを押しながらクリックすると時間短縮できます。)
STEP.2
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.3
マクロを再生
連続で複数回マクロを再生します。
STEP.4
データを確認
抜き出したデータがちゃんと保存されているか確認します。

※動画(約6分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

楽天電子書籍ランキングのページにアクセス

https://books.rakuten.co.jp/ranking/hourly/101/#!/1/0/

2

記憶を開始する

imacros-recored

3

抜き出したい場所をクリックする

楽天ランキング extract

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「楽天ランキング.iim」に変更しておきましょう。
マクロ名の変更
楽天ランキング extract


【STEP.2】マクロを編集

1

編集画面を開く

楽天ランキング extract
先ほど自動で作成されたマクロは以下のようになっています。

iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://books.rakuten.co.jp/ranking/hourly/101/#!/1/0/
TAG POS=1 TYPE=IMG ATTR=SRC:https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/9675/2000007479675.jpg?fitin=360:360&&ALT:ヤングマガジン
TAG POS=1 TYPE=A ATTR=HREF:https://books.rakuten.co.jp/rk/2259c43095313c759ded3f5ed72c92a2/&&CLASS:txt-ellipsis
TAG POS=1 TYPE=P ATTR=CLASS:author
TAG POS=1 TYPE=P ATTR=CLASS:subinfo
TAG POS=1 TYPE=P ATTR=CLASS:price
TAG POS=1 TYPE=IMG ATTR=SRC:https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/3710/2000007393710.jpg?fitin=360:360&&ALT:ゴールデンカムイ18
TAG POS=1 TYPE=A ATTR=HREF:https://books.rakuten.co.jp/rk/082fdab94d183c94a8358c5206ecc58f/&&CLASS:txt-ellipsis
TAG POS=2 TYPE=P ATTR=CLASS:author
TAG POS=2 TYPE=P ATTR=CLASS:subinfo
TAG POS=2 TYPE=P ATTR=CLASS:price
※書籍タイトルは、アクセスする日によって変わります。
マクロを編集する時に全て削除しますので違っていても問題ありません。
2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
コピー 拡大
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'1番から順番に1→2→3…と数値が増える
SET !LOOP 1

'吸い出す文字を確認しない設定(ポップアップをOFF)
SET !EXTRACT_TEST_POPUP NO

'URLをコメントアウトにして読み込まないようにする←重要
'URL GOTO=https://books.rakuten.co.jp/ranking/hourly/101/#!/1/0/

'「画像」を抜き出す
TAG POS={{!LOOP}} TYPE=IMG ATTR=SRC:https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/* CONTENT=EVENT:SAVEITEM

'「タイトルとリンク先URL」を抜き出す
TAG POS={{!LOOP}} TYPE=A ATTR=HREF:https://books.rakuten.co.jp/rk/*/&&CLASS:txt-ellipsis EXTRACT=TXT
TAG POS={{!LOOP}} TYPE=A ATTR=HREF:https://books.rakuten.co.jp/rk/*/&&CLASS:txt-ellipsis EXTRACT=HREF

'「作者名」を抜き出す
TAG POS={{!LOOP}} TYPE=P ATTR=CLASS:author EXTRACT=TXT

'「掲載日 出版社」を抜き出す
TAG POS={{!LOOP}} TYPE=P ATTR=CLASS:subinfo EXTRACT=TXT

'「値段」を抜き出す
TAG POS={{!LOOP}} TYPE=P ATTR=CLASS:price EXTRACT=TXT

'吸い出したデータを「Downloadsフォルダ」に保存する
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
なぜURLを読み込まないようにするの?

1つのデータ(画像、タイトル、リンク先URL、掲載日 出版社、値段)毎にアクセスして、データを取得すると通常より時間が掛かります。

それと何度も短時間に大量のアクセスしますので、サーバーに負荷が掛かる可能性があります。

今後、大量のデータを取得する予定ある方は特に注意しましょう。


【STEP.3】マクロを再生

1

作成したマクロをクリックする

楽天ランキング extract

2

Loop回数を変更する

30位まであるのでMax:30に変更します。
楽天ランキング extract


【STEP.4】データを確認

1

Downloadsフォルダを開く

Download

2

抜き出したデータを開く

以下のようになっていればOKです。
楽天ランキング extract

注意
もし画像をご自分のサイトで使用する場合は、転用・転載が可能かどうかご自身で確かめましょう。特にアフィリエイトをされている方は、各ASP規約の確認が必須です。

楽天ランキング extract

4. 各コマンドの解説

コマンド目次
SET !EXTRACT_TEST_POPUP NO EXTRACT=TXT
EXTRACT=HREF EXTRACT=HTM
CONTENT=EVENT:SAVEITEM SAVEAS TYPE=EXTRACT FOLDER=*
*(ワイルドカード)

SET !EXTRACT_TEST_POPUP NO

iim
コピー 拡大
SET !EXTRACT_TEST_POPUP NO
解説
  • SET
    次の動作を指定
  • !EXTRACT(エクストラック)
    抜き出し
  • TEST_POPUP(テスト_ポップアップ)
    抜き出し箇所をテスト表示
  • NO
    しない

EXTRACTコマンドを使った場合、どこの場所を抜き出しているかテスト表示される仕様になっています。

SET !EXTRACT_TEST_POPUP NO

上記のように抜き出し箇所を表示させて確認できますが、OKを押さないと次に進みません。

マクロが完成した後にSET !EXTRACT_TEST_POPUP NOを追加して非表示しておきましょう。

EXTRACT=TXT

iim
コピー 拡大
EXTRACT=TXT
解説
  • EXTRACT
    抜き出す
  • TXT
    文字列

EXTRACT=TXTは文字列(英数字、ひらがな、漢字)を抜き出す事ができるコマンドです。

EXTRACT=HREF

iim
コピー 拡大
EXTRACT=HREF
解説
  • EXTRACT
    抜き出す
  • HREF(エイチレフ)
    リンク先URL

EXTRACT=HREFはリンク先URL抜き出すコマンドです。

覚える必要はありませんが、HREFは「Hypertext Reference ハイパーテキスト リファレンス」の略です。

EXTRACT=HTM

iim
コピー 拡大
EXTRACT=HTM
解説
  • EXTRACT
    抜き出す
  • HTM
    HTML

EXTRACT=HTMはHTMLを抜き出すコマンドです。

CONTENT=EVENT:SAVEITEM

iim
コピー 拡大
CONTENT=EVENT:SAVEITEM
解説
  • CONTENT=EVENT:SAVEITEM
    画像を保存

CONTENT=EVENT:SAVEITEMは画像を抜き出すコマンドです。

SAVEAS TYPE=EXTRACT FOLDER=*

iim
コピー 拡大
SAVEAS TYPE=EXTRACT FOLDER=*
解説
  • SAVEAS
    保存する
  • TYPE=EXTRACT
    EXTRACTで抜き出したデータ
  • FOLDER=*
    保存先をDownloadフォルダに指定

SAVEAS TYPE=EXTRACT FOLDER=*EXTRACTで抜き出したものを保存するコマンドです。

保存する場所を変更したり、ファイル名を「extract」から違う名前変更することも可能です。

例えばFOLDER=C:UsersPCのユーザー名Desktop FILE=テスト.csvにするとデスクトップ上に「テスト」というファイル名で保存もできます。

補足
画像データだけは変更することができません。EXTRACTコマンドを使用した場合に抜き出す「文字」「URL」「HTML」のみです。

フォルダ場所を確認する方法は以下の通りです。(デスクトップの場合)

1

プロパティを開く

フォルダ場所変更

2

場所を確認する

フォルダ場所変更

*(ワイルドカード)

iim
コピー 拡大
*
*(ワイルドカード)はトランプで例えるならジョーカーの役割をします。

どんな文字列(英数字、記号、ひらがな、漢字など)にも置き換わります。

例えば以下のようなURLがあるとします。

https://teilab-sub.net/sample/02
https://teilab-sub.net/sample/08
https://teilab-sub.net/category/sample/
https://teilab-sub.net/?p=200
https://teilab-sub.net/?p=2525

https://teilab-sub.net/は全て同じで、その後の文字だけが変化しています。

この場合https://teilab-sub.net/*(ワイルドカード)にすることによって、どんな文字に変わっても対応することができます。

解説
  • *
    ワイルドカード
※厳密に言うとコマンドではありません。

5. よくあるエラー事例

RuntimeError: element IMG specified by SRC:https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/9675/2000007479675.jpg?fitin=360:360&&ALT:ヤングマガジン was not found, line 14 (Error code: -921)

抜き出す画像が見つからないときのエラーです。

解決方法は、URLの部分をワイルドカードに変更すれば大丈夫です。
「https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/9675/2000007479675.jpg?fitin=360:360&&ALT:ヤングマガジン

「https://tshop.r10s.jp/rakutenkobo-ebooks/cabinet/*

NS_ERROR_FILE_UNRECOGNIZED_PATH: Component returned failure code: 0x80520001 (NS_ERROR_FILE_UNRECOGNIZED_PATH) [nsILocalFile.append], line 30 (Error code: -1001)

デフォルトの「Downloadフォルダ」から変更した場合に、存在しない保存場所を指定した時に表示されます。

例えばデスクトップに保存する場合は、以下の流れで場所を確認します。

1

プロパティを開く

フォルダ場所変更

2

場所を確認する

フォルダ場所変更

「SAVEAS TYPE=EXTRACT FOLDER=* FILE=*

「SAVEAS TYPE=EXTRACT FOLDER=* FILE=C:Users\PC\Desktop
※バックスラッシュ()は¥マークと同じです。

SET !EXTRACT_TEST_POPUP NO

SET !EXTRACT_TEST_POPUP NOを入れれば表示されなくなります。

6. まとめ

今回【PART.5】ではEXTRACTを使って色々なデータを抜き出す方法をお伝えしました。

このコマンドがiMacrosで一番難易度が高い項目になります。自分で作成できなかった方は、動画を見ながら練習して頂ければと思います。

【PART.5】まとめ
  • 文字はEXTRACT=TXT
  • URLはEXTRACT=HREF
  • HTMLはEXTRACT=HTM
  • 画像はCONTENT=EVENT:SAVEITEM
  • 画像以外のデータの保存場所は変更できる
  • 取得するデータが多い場合はURL GOTOをコメントアウトにして読み込まないようにする

次回予告

次回【PART.6】は今までお伝えしてきたマクロとは違い、特定の場所のみ手動入力に切り替える方法です。

画像認証や同じ内容ではない場合に、臨機応変に対応できるコマンドのご紹介です。
iMacros:PROMPTと!VARで特定の場所を手動入力にする【PART.6】