未経験のITエンジニア転職【テックキャンプ】

iMacros:CSVファイル(DATASOURCE)データを利用して自動入力【PART.4】

iMacrosのコマンドdataSource(CSVファイル)を利用して自動入力

このページ【PART.4】では、ボタン1つで大量のデータを特定のフォームに文字を入力したり、ブログに記事を入れたりする方法をご紹介しています。

使うコマンドはSET !DATASOURCE(セット!データソース)と言います。

iMacrosでは、『データソース』=『CSVファイル』と覚えておきましょう。

ノーノちゃん

DATASOURCE?CSVファイル?何のことなのか全然イメージわかないよ(T_T)
1個ずつ順番にご説明しますので安心してくださいね。

テイくん

1. データソースとは?

冒頭でお伝えした通り、iMacrosのデータソースというのはCSVファイルのことです。

iMacrosで使用できるファイルはCSVファイルのみです。エクセル形式(.xlsx)は使用できませんので注意が必要です。

それでは、実際に使用する画面を確認してみましょう。

iMacrosで使用するデータソース(CSVファイル)

上記に書いてあるデータを、上から順番に自動で入力させることができます。

使用しているのはsmoothCSV(スムースシーエスブイ)という無料ソフトです。

まだダウンロードされていない方は、先に入れておいてくださいね。

導入方法はこちらから SmoothCSV

ノーノちゃん

ExcelでもCSVファイル作れるけど…なんでsmoothCSVが必要なの?
確かにExcelでもできますが、smoothCSVの方が使い勝手がいいです。理由は次の項目でご説明しますね。

テイくん

smoothCSVを使う理由

理由は大まかに分けて3つあります。

①設定が簡単

ExcelでCSVファイルを作成する場合、ファイル形式を通常の .xlsx(Excelブック)から.csv(カンマ区切り)に変更する必要があります。

それとCSVファイルに保存する時、毎回以下のようなメッセージが表示されます。
ExcelCSV保存時、確認メッセージ

smoothCSVの場合は、最初の設定さえ終われば、その後は保存を押すだけなので凄く簡単です。


②動作が軽い

少ないデータであればExcelでも問題ありませんが、データ量が多くなると読み込みが遅くなります。

smoothCSVの場合は、大量のデータがあってもすぐに開きます。極端な例を上げますと10,000行以上あっても遅くなりません。


③エラーが起きにくい

ExcelでCSVファイルを使用した場合、文字化けが起きたり、セル内に改行が入っているとiMacros起動時にエラーが起きたりします。

ここで詳しくは説明しませんが、エラーの原因を突き止めるのが非常に面倒です。

ノーノちゃん

なるほど、とりあえずsmoothCSVがスムーズって言うことだね。
最初はExcelを使用していましたが、何回もエラーが起きて大変だったので、今はsmoothCSVしか使わないようにしています。

テイくん

2. CSVファイルを使ったマクロを作成

少し前置きが長くなりましたが、SET !DATASOURCEを使ってフォームに入力する自動マクロを作成していきます。

まずは、分かりやすいようにGoogleの検索フォームでシンプルなマクロをご紹介します。

注意
最新バージョンのiMacros(無料版)ではSET !DATASOURCEは使えません!
もし使いたい場合はダウングレードする必要があります。

導入の仕方はこちら
iMacrosの初期設定と導入方法iMacrosに必要なFirefox、SmoothCSVの導入方法と初期設定(保存版)【PART.1】

①Google検索編

SET !DATASOURCEを使う場合、自動でマクロが記憶してくれるわけではないので、自分で作成する部分が出てきます。

最初は少し難しいと感じますが、どんなデータであってもいつもすることは同じです。

一度覚えれば、次回から簡単に作成できるようになります。

サンプルマクロ
google検索に作成したデータを上から順番に入力する。

作業の流れ

STEP.1
マクロを作成
google検索に適当な文字を入力してマクロを保存する。
STEP.2
CSVファイルを作成
SmoothCSVを使ってデータソース(google.csv)を作る。
STEP.3
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.4
マクロを再生
連続で複数回マクロを再生します。

※動画(約3分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

Googleにアクセス

https://www.google.com/

2

記憶を開始する

imacros-recored

3

検索フォームに文字を入力

入力する文字を「テスト」にしていますが、後で編集しますのでなんでもOKです。
Google検索

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「google.iim」に変更しておきましょう。
マクロ名の変更
googleに名前変更

変更する理由は、新しくマクロを作成すると「#Current.iim」のままですと上書きされて消えてしまします。

6

完成したマクロを確認する

編集画面imacros
先ほど自動で作成されたマクロは以下のようになっています。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://www.google.com/
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:tsf ATTR=NAME:q CONTENT=テスト
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ID:tsf ATTR=NAME:btnK


【STEP.2】CSVファイルを作成

1

smoothCSVを立ち上げる

smoothCSV

2

データを作成する

smoothCSV使い方

3

保存画面を開く

smoothCSV使い方

4

名前を変更して保存する

デスクトップに保存していますが、直接「Datasourceフォルダ」に入れてもOKです。
smoothCSV使い方
※フォルダ名を間違えるとマクロが動きませんので注意が必要です。

5

Datasourceフォルダに移動する

smoothCSV使い方

補足
imacrosの保存されているフォルダ場所がわからない場合は、iMacrosの保存先を変更の記事が参考になると思います。
注意
CSVファイルは必ず「Datesourcesフォルダ」に入れる必要があります。もし違う場所に入れたりするとエラーが発生してマクロが動きません。

【STEP.3】マクロを編集

1

編集画面を開く

編集画面imacros
先ほど【STEP.1】で作成した以下のマクロを編集していきます。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://www.google.com/
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:tsf ATTR=NAME:q CONTENT=テスト
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ID:tsf ATTR=NAME:btnK

2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'「google.csv」ファイルを指定
SET !DATASOURCE google.csv

'1番から順番に2→3→4と数値が増える ※Play(Loop)で再生した場合のみ
SET !LOOP 1

'今回は上のLoopで指定した数値は1ですので「google.csv」の1行目から2行目→3行目の順番に増えます
SET !DATASOURCE_LINE {{!LOOP}}

'googleにアクセス
URL GOTO=https://www.google.com/

'検索フォームに「google.csv」の1列目を入力
'※「テスト」を{{!COL1}}に変更しています
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:tsf ATTR=NAME:q CONTENT={{!COL1}}

'google検索をクリック
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ID:tsf ATTR=NAME:btnK
マクロとCSVファイルの早見図
補足
わからないコマンドが多数あると思いますが、意味を覚えるより動かしたほうが早く理解できます。ここではあまり気にせず、次の項目に進むことをおすすめします。
※各コマンドの詳しい解説はページ下で解説しています。

【STEP.4】マクロを再生

1

作成したマクロをクリックする

googleiimを再生

2

Loop回数を変更する

先ほど作成した「google.csv」ファイルは5行目まで記入しています。

ですので、5行目まで使用するように設定をMax:5に変更します。
iMacros繰り返し再生

Maxの数値について
何行目まで使うかによってMaxの数値を変更します。

  • 10行目までの場合はMax:10
  • 50行目までの場合はMax:50
  • 100行目までの場合はMax:100

②楽天のCDランキング編

上の項目(Google検索編)では1列目のみのデータでしたが、今度は複数列あるデータを自動入力していきます。

作り方は大きくは変わりませんがマクロが少し長くなります。それでは先ほどと同じく順番に作成していきます。

サンプルマクロ
楽天のCDランキング編【練習用フォーム】に作成したデータを上から順番に入力する。

作業の流れ

STEP.1
マクロを作成
楽天のCDランキング編【練習用フォーム】の各項目に適当な文字を入力してマクロを保存する。
STEP.2
CSVファイルを作成
SmoothCSVを使ってデータソース(rakuten.csv)を作る。
STEP.3
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.4
マクロを再生
連続で複数回マクロを再生します。

※動画(約4分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

楽天のCDランキング編【練習用フォーム】にアクセス

https://teilab-sub.net/?p=9

2

記憶を開始する

imacros-recored

3

フォームに文字を入力

楽天フォーム
同じ名前を書き込む理由は、後で見て分かりやすくするためです。ただ、このフォームは項目が少ないので数字でもOKです。

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「rakuten.iim」に変更しておきましょう。
マクロ名の変更
rakutenに名前変更

6

完成したマクロを確認する

編集
先ほど自動で作成されたマクロは以下のようになっています。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=9
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:item-details CONTENT=商品名
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:author-name CONTENT=アーティスト名
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:subinfo CONTENT=発売日、販売元などの情報
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:price CONTENT=価格
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=*


【STEP.2】CSVファイルを作成

1

smoothCSVを立ち上げる

smoothCSV

2

データを貼り付け

今回は事前に自動入力するデータを用意しました。

下記の表データを全てコピーしてsmoothCSVにそのまま貼り付けます。

商品名 アーティスト名 発売日、販売元などの情報 価格
5×20 All the BEST!! 2019年06月26日    (株)ジェイ・ストーム 4,599円(税込)
Summer Trap!! WANIMA 2019年07月17日    (株)ワーナーミュージック・ジャパン 1,512円(税込)
NEW LOVE B`z 2019年05月29日    (株)ビーイング 3,899円(税込)
aikoの詩。 aiko 2019年06月05日    (株)ポニーキャニオン 3,542円(税込)
Rain 亀梨和也 2019年05月15日    (株)ジェイ・ストーム 3,780円(税込)
King & Prince King & Prince 2019年06月19日    Johnnys’ Universe 3,888円(税込)
NEW LOVE B`z 2019年05月29日    (株)ビーイング 3,200円(税込)
Turntable 竹内まりや 2019年08月21日    (株)ワーナーミュージック・ジャパン 4,320円(税込)
トップガン / Love Story NEWS 2019年06月12日    (株)ジャニーズ・エンタテイメント 1,512円(税込)
CHANGE 山下智久 2019年06月19日    (株)ソニー・ミュージックレーベルズ 1,500円(税込)

「楽天ブックス」のCD別売上げランキングのデータです。
※商品名が長いので少し省略しています。
 
楽天CSV
上記はデータを貼り付けした後です。

3

保存画面を開く

smoothCSV

4

名前を変更して保存する

デスクトップに保存していますが、直接「Datasourceフォルダ」に入れてもOKです。
楽天CSV
※フォルダ名を間違えるとマクロが動きませんので注意が必要です。

5

Datasourceフォルダに移動する

楽天CSV


【STEP.3】マクロを編集

1

編集画面を開く

編集
先ほど【STEP.1】で作成した以下のマクロを編集していきます。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=9
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:item-details CONTENT=商品名
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:author-name CONTENT=アーティスト名
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:subinfo CONTENT=発売日、販売元などの情報
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:price CONTENT=価格
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=*

2

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'「rakuten.csv」ファイルを指定
SET !DATASOURCE rakuten.csv

'2番から順番に2→3→4…と数値が増える
SET !LOOP 2

'今回は上のLoopで指定した数値は2ですので「rakuten.csv」の2行目から3行目→4行目の順番に増えます
SET !DATASOURCE_LINE {{!LOOP}}

'楽天のCDランキング編【練習用フォーム】にアクセス
URL GOTO=https://teilab-sub.net/?p=9

'商品名に「rakuten.csv」の1列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:item-details CONTENT={{!COL1}}

'アーティスト名に「rakuten.csv」の2列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:author-name CONTENT={{!COL2}}

'発売日、販売元などの情報に「rakuten.csv」の3列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:subinfo CONTENT={{!COL3}}

'価格に「rakuten.csv」の4列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=NAME:price CONTENT={{!COL4}}

'確認ボタンををクリック
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=9#wpcf7-f8-p9-o1 ATTR=*
マクロとCSVファイルの早見図

【STEP.4】マクロを再生

1

作成したマクロをクリックする

rakuteniimクリック

2

Loop回数を変更する

先ほど作成した「rakuten.csv」ファイルは11行目まで記入しています。

ですので、11行目まで使用するように設定をMax:11に変更します。
iMacros繰り返し再生

③ブログ記事編

無料ブログやWordpress(ワードプレス)などに、大量の記事を入れる時に便利なマクロを作成していきます。

記事を外注化されている方や、複数サイトを持っている方にも役立ちます。

それでは順番に確認していきましょう。

サンプルマクロ
ブログ記事編【練習用フォーム】の記事タイトル、URL、本文とカテゴリに作成したデータを自動入力する。

作業の流れ

STEP.1
マクロを作成
ブログ記事編【練習用フォーム】の各項目に適当な文字を入力してマクロを保存する。
STEP.2
CSVファイルを作成
SmoothCSVを使ってデータソース(blog.csv)を作る。
STEP.3
マクロを編集
自動で作成されたマクロに、コマンドを追加したり編集する。
STEP.4
マクロを再生
連続で複数回マクロを再生します。

※動画(約4分)を確認後、下の解説を読んで頂くと分かりやすいと思います。


【STEP.1】マクロを作成

1

ブログ記事編【練習用フォーム】にアクセス

https://teilab-sub.net/?p=24

2

記憶を開始する

imacros-recored

3

フォームに文字を入力

blogフォーム

4

記憶を終了する

imacros-stop

5

名前を変更する(省略可)

「#Current.iim」から「blog.iim」に変更しておきましょう。
マクロ名の変更
リネイム

5

完成したマクロを確認する

マクロを確認
先ほど自動で作成されたマクロは以下のようになっています。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=24
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:title CONTENT=記事タイトル
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:url CONTENT=url
TAG POS=1 TYPE=TEXTAREA FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:article CONTENT=本文
TAG POS=1 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=2 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=3 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=4 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=5 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=*


【STEP.2】CSVファイルを作成

1

smoothCSVを立ち上げる

smoothCSV

2

データを貼り付け

下記の表データを全てコピーしてsmoothCSVにそのまま貼り付けます。

記事タイトル URL(パーマリンク) 本文 カテゴリ
ニュース① news1 ここにニュース①の記事が入ります。 1
ニュース② news2 ここにニュース②の記事が入ります。 1
芸能① entertainment1 ここに芸能①の記事が入ります。 2
芸能② entertainment2 ここに芸能②の記事が入ります。 2
スポーツ① sports1 ここにスポーツ①の記事が入ります。 3
スポーツ② sports2 ここにスポーツ②の記事が入ります。 3
音楽① music1 ここに音楽①の記事が入ります。 4
音楽② music2 ここに音楽②の記事が入ります。 4
その他① other1 ここにその他①の記事が入ります。 5
その他② other2 ここにその他②の記事が入ります。 5

カテゴリ列の数字(1、2、3など)は後ほどマクロの作成する項目で、ご説明しますので気にせず進みましょう。

blog.csv
上記はデータを貼り付けした後です。

3

保存画面を開く

smoothCSV

4

名前を変更して保存する

デスクトップに保存していますが、直接「Datasourceフォルダ」に入れてもOKです。
blog.csv
※フォルダ名を間違えるとマクロが動きませんので注意が必要です。

5

Datasourceフォルダに移動する

blog.csv


【STEP.3】マクロを編集

1

編集画面を開く

マクロを確認
先ほど【STEP.1】で作成した以下のマクロを編集していきます。

iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=24
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:title CONTENT=記事タイトル
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:url CONTENT=url
TAG POS=1 TYPE=TEXTAREA FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:article CONTENT=本文
TAG POS=1 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=2 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=3 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=4 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=5 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=*

2

いらないマクロを削除

今回のマクロは今までとは違い、1つだけ残して他を削除する必要がある部分があります。
それは以下のカテゴリをクリックした時のマクロです。

iim
TAG POS=1 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=2 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=3 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=4 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES
TAG POS=5 TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES

ノーノちゃん

え、いらないんだったら初めからカテゴリの所、全てクリックする必要ないんじゃないの?
全てクリックした理由は、どのカテゴリが何番になっているか確かめるためです。これから詳しく説明しますね。

テイくん

TAG POS=1TAG POS=2と順番に数字が増えています。全て順番にクリックしたことによって以下のような関係になっていることが分かります。

TAG POSの関係

WEBに詳しい方の場合は、クリックしなくてもどのような作り(要素)を確認すればすぐに分かります。

ただ間違えも起きやすいので、クリックして確認するのが一番楽な方法です。

補足
Wordpressや無料ブログなどのカテゴリは、順番に数値が増えるのではなく不規則な場合が多いです。また別ページで詳しくご紹介さして頂きます。
3

マクロを編集する

赤色:追加した部分
オレンジ色:変更した部分
緑色:メモ書き(コメントアウト)
iim
VERSION BUILD=8970419 RECORDER=FX
TAB T=1

'「blog.csv」ファイルを指定
SET !DATASOURCE blog.csv

'2番から順番に2→3→4…と数値が増える
SET !LOOP 2

'上のLoopで指定した数値は2ですので「blog.csv」の2行目から3行目→4行目の順番に増えます
SET !DATASOURCE_LINE {{!LOOP}}

'ブログ記事編【練習用フォーム】にアクセス
URL GOTO=https://teilab-sub.net/?p=24

'記事タイトルに「blog.csv」の1列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:title CONTENT={{!COL1}}

'URL(パーマリンク)に「blog.csv」の2列目を入力
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:url CONTENT={{!COL2}}

'本文に「blog.csv」の3列目を入力
TAG POS=1 TYPE=TEXTAREA FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:article CONTENT={{!COL3}}

'カテゴリに「blog.csv」の4列目の場所をクリック
TAG POS={{!COL4}} TYPE=INPUT:CHECKBOX FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=NAME:category[] CONTENT=YES

'確認ボタンををクリック
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=24#wpcf7-f27-p24-o1 ATTR=*
マクロとCSVファイルの早見図

【STEP.4】マクロを再生

1

作成したマクロをクリックする

blog.iim選ぶ

2

Loop回数を変更する

先ほど作成した「blog.csv」ファイルは11行目まで記入しています。

ですので、11行目まで使用するように設定をMax:11に変更します。
iMacros繰り返し再生

3. 各コマンドの解説

コマンド目次
SET !DATASOURCE SET !LOOP
{{!LOOP}} SET !DATASOURCE_LINE
{{!COL}} LINEと{{!COL}}の関係

SET !DATASOURCE

iim
SET !DATASOURCE google.csv
SET !DATASOURCE rakuten.csv
SET !DATASOURCE blog.csv
解説
  • SET
    次の動作を指定
  • !DATASOURCE(データソース)
    データ(CSVファイル)を使用

他の形式(.txt、.xlsx、.xlsなど)は使用できませんので必ず.csvに変更する必要があります。

データソースフォルダ
Datasourcesフォルダに入っているCSVファイルを使用することができます。

SET !LOOP

iim
SET !LOOP 1
SET !LOOP 2
解説
  • SET
    次の動作を指定
  • !LOOP
    繰り返す

SET !LOOPは繰り返し再生Play(Loop)を使う時に使用します。

  • SET !LOOP 1の場合は、1から順番に1→2→3→4…と増える。
  • SET !LOOP 2の場合は、2から順番に2→3→4→5…と増える。

{{!LOOP}}

iim
{{!LOOP}}
解説
  • {{!LOOP}}
    SET !LOOPで指定した数値から使用

{{!LOOP}}は、上記の項目のSET !LOOPで指定した数値が入ります。

注意
SET !LOOPを使う場合は必ず{{!LOOP}}とセットで使用します。

SET !DATASOURCE_LINE

iim
SET !DATASOURCE_LINE {{!LOOP}}
解説
  • SET
    次の動作を指定
  • !DATASOURCE_LINE {{!LOOP}}
    SET !LOOPで指定した行から使用

SET !DATASOURCE_LINEは、どの行から開始するか指定する時に使います。それとLINE=行と覚えておきましょう。

{{!COL}}

iim
{{!COL1}} {{!COL2}} {{!COL3}} {{!COL4}} 
解説
  • {{!COL}}
    指定した列(カラム)を使用

英語で書いているので分かりにくいですがCOL列(カラム)のことです。COL=列と覚えておきましょう。

  • {{!COL1}} =CSVファイルの1列(カラム)目
  • {{!COL2}} =CSVファイルの2列(カラム)目

注意
SET !DATASOURCE_LINEを使う場合は必ず{{!COL}}とセットで使用します。

LINEと{{!COL}}の関係

LINEと{{!COL}}について分かりにくかった方は、以下の図を参考にしてみましょう。

LINE
SET !DATASOURCE_LINEのコマンドでSET !LOOPで指定した行から使用しています。
COLカラム
このページでは{{!COL1}} {{!COL4}}まで使用しています。

4. よくあるエラー事例

undefined
{{!COL}} が半角ではなく全角になっていたり、つづりが間違っている時に表示されます。
指定したデータ(CSVファイル)が見つかりませんというエラーです。
CSVファイルの名前が間違っていないかもう一度確認しましょう。
10行目のコマンドに間違いがありますというメッセージです。
空白を全角にしていたり、つづりが間違っていないか確認しましょう。

5. まとめ

今回【PART.4】ではDATASOURCEの使い方についてお伝えしました。

理解しにくい部分があったと思いますが、iMacrosで使用頻度高いコマンドです。今回ご紹介した場所以外でも使用できますので、練習のために作成してみましょう。

【PART.4】まとめ
  • DATASOURCEはCSVファイルのみ使用可能
  • SET !LOOP{{!LOOP}}は必ずセットで使用
  • SET !DATASOURCE_LINE{{!COL}}は必ずセットで使用
  • LINE=行 COL=列

次回予告

次回【PART.5】はデータを抜き出す方法について解説しています。

DATASOURCEと同じくらい使用頻度が高いコマンドです。
EXTRACTを使用して特定の文字、画像やHTMLを抜き出す iMacros:EXTRACTで文字、HTML、画像を抜き出す【PART.5】