Amazon 数量限定タイムセール開催中

iMacros：コマンド一覧と使い方（大量のサンプルマクロあり）【PART.10】

iMacrosコマンド一覧と使い方

SHARE

前回の【PART.9】
iMacros　POSとXPATHの使い方iMacros：TAGコマンドのPOSとXPATHのを使い分ける基準と使い方【PART.9】

このページ【PART.10】では、今までの【PART.0~9】で出てきたコマンドとそれ以外のコマンドを一覧でご紹介します。

各コマンドごとに使い方とサンプルマクロを入れていますが、読んでもわからない場合が結構あると思います。

その場合は、サンプルマクロをコピーしてご自分のPCで一度動かしてみましょう。

ノーノちゃん

とりあえず分からなければ、自分のPCで動かせばいいって事？
はい！どんな感じに動くのか見た方が、早く理解できると思います(^○^)

テイくん

1. コマンド目次

時間調節
!REPLAYSPEED 速度調節する
WAIT 待ち時間を入れる
PAUSE 一時停止する
!SINGLESTEP 1マクロ毎に一時停止する
!TIMEOUT_STEP タイムアウト時間を変更する
動作補助
!ERRORIGNORE エラーを回避する
!LOOP 繰り返し再生する
BACK 1つ前のページに戻る
CLEAR キャッシュを削除する
REFRESH ページを更新する
FILTER 画像を非表示する
場所指定
URL GOTO アクセスするサイトを指定する
TAB どのタブを使うか指定する
TAG POS POSを使って場所を指定する
TAG XPATH XPATHを使って場所を指定する
CLICK クリックする場所を座表で指定する
ONDIALOG ダイアログ表示時の動作を指定する
データ入力
!DATASOURCE データソース（.CSV）を使用する
!VAR 文字列やコマンドを保存したもので入力する
PROMPT 入力ボックスを表示して入力する
EVAL 文字や数値をランダムで入力する
※iMacros内でJavaScriptを使用するコマンドなので入力以外の用途でも使用可
!CLIPBOARD クリップボードを使用する
!NOW 現在の時刻などを入力する
データ抜き出し
EXTRACT 個別に文字列、URLなどを抜き出す
!EXTRACT_TEST_POPUP ポップアップを非表示（ブロック）する
NULL 抜き出したデータを破棄する
SAVEITEM 画像を抜き出す
SAVE ページ全体のデータを全て抜き出す
!URLCURRENT 開いているページURLを抜き出す
ONDOWNLOAD ソフト、PDFなどをダウンロードする
その他
VERSION バージョン情報
'(コメントアウト) 注書きやメモを入れる
*(ワイルドカード) どんな文字列（文字、数字、ローマ字）にも置き換わる
全てのコマンド iMacrosで使える全てのコマンド一覧
目次の並び順について
各項目の上から使用頻度が高い順に並べています。

2. 時間調節

!REPLAYSPEED

iim
コピー 拡大 
SET !REPLAYSPEED FAST
SET !REPLAYSPEED MEDIUM
SET !REPLAYSPEED SLOW
FAST 待ち時間なし
※デフォルト設定
MEDIUM コマンド間に1秒間の待ち時間
SLOW コマンド間に2秒間の待ち時間
待ち時間
図のようにコマンド間に待ち時間を入れるとエラーが起きにくくなります。

例えば、ページを読み込む前に次のコマンドを実行しようとするとエラーが起きます。

そんな時は、SET !REPLAYSPEED MEDIUMを入れて再度マクロを動かしてみましょう。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED FAST
TAB T=1
URL GOTO=https://teilab.net/
URL GOTO=https://teilab.net/category/camera/
URL GOTO=https://teilab.net/category/wordpress/
URL GOTO=https://teilab.net/category/imacros/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab.net/
URL GOTO=https://teilab.net/category/camera/
URL GOTO=https://teilab.net/category/wordpress/
URL GOTO=https://teilab.net/category/imacros/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED SLOW
TAB T=1
URL GOTO=https://teilab.net/
URL GOTO=https://teilab.net/category/camera/
URL GOTO=https://teilab.net/category/wordpress/
URL GOTO=https://teilab.net/category/imacros/

コマンド目次に戻る

WAIT

iim
コピー 拡大 
WAIT SECONDS=秒数
例えば秒数に3を入れた場合は、3秒の待ち時間を作ります。

使う場面はマクロが早すぎて失敗する時、サーバーに負荷をかけないようする時などです。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
WAIT SECONDS=10
TAB T=1
URL GOTO=https://teilab-sub.net/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
WAIT SECONDS=300
TAB T=1
URL GOTO=https://teilab-sub.net/

コマンド目次に戻る

PAUSE

iim
コピー 拡大 
PAUSE
一時停止
マクロを特定の場所で止めたいときに使います。再開する場合はContinueを押します。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
PAUSE
URL GOTO=https://teilab.net/

コマンド目次に戻る

!SINGLESTEP

iim
コピー 拡大 
SET !SINGLESTEP YES
SET !SINGLESTEP NO
YES 1コマンド毎にマクロを止める
NO 1コマンド毎にマクロを止めない
※デフォルト設定

簡単に言うと、「1行づつコマンドをチェックしたいので毎回止まってね」という感じのコマンドです。

主に、エラー箇所の確認やマクロが長い時に使います。

再開するにはContinueを押します。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !SINGLESTEP YES
TAB T=1
URL GOTO=https://teilab.net/category/imacros/
TAG POS=1 TYPE=A ATTR=CLASS:cardtype__link

コマンド目次に戻る

!TIMEOUT_STEP

iim
コピー 拡大 
SET !TIMEOUT_STEP 秒数
ステップ（1行）ごとのタイムアウトする時間を設定できます。

タイムアウトの意味は、時間内にコマンドが終わらなければマクロを止めることを言います。

デフォルトは60秒に設定されていますが、時間を調節したい時に使います。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
SET !TIMEOUT_STEP 2
URL GOTO=https://teilab.net/
TAG POS=1 TYPE=A ATTR=href:https://teilab.net/category/imacros/

コマンド目次に戻る

3. 動作補助

!ERRORIGNORE

iim
コピー 拡大 
SET !ERRORIGNORE YES
SET !ERRORIGNORE NO
YES エラーがあってもそのまま次のコマンドを実行
NO エラーがあったらマクロが止まる
※デフォルト設定

簡単に言うと、「エラーがあっても気にせず進んでね」という感じのコマンドです。

例えば、3サイトにアクセスするマクロを作った場合、そのうちの1サイトだけアクセスできなかったら通常そこで止まります。

SET !ERRORIGNORE YESを入れると、止まらず他のサイトにアクセスしてくれます。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
SET !ERRORIGNORE YES
TAB T=1
URL GOTO=https://yahoo.co.jp/
'↓存在しないURL
URL GOTO=https://aaa.net/
URL GOTO=https://teilab.net/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
SET !ERRORIGNORE YES
TAB T=1
URL GOTO=https://teilab-sub.net
'↓作り方が間違っている
TAG POS=1 TYPE=H2 ATTR=TXT:文字ランダム
TAG POS=1 TYPE=H2 ATTR=TXT:文字ランダム【練習用フォーム】

コマンド目次に戻る

!LOOP

iim
コピー 拡大 
SET !LOOP 番号
{{!LOOP}}
繰り返し
必ずPlay(LOOP)ボタンを押して再生する必要があります。

簡単に言うと「最初に決めた数値から1づつ増やして使ってね」という感じのコマンドです。

例えば番号に2を入れます。そうすると2から順番に2→3と増えていきます。

それとMAXの数値を99999に変更すると2→3→4…99999まで数値を増やすこともできます。
※iMacrosのバージョンや使用ブラウザによっては上限数が違います。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
SET !LOOP 1
URL GOTO=https://teilab-sub.net/{{!LOOP}}
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
SET !LOOP 1
TAG POS={{!LOOP}} TYPE=H2 ATTR=TXT:*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
'※iMacrosダウンロード時に元々入ってるAddress.csvを使っています。
'※削除されている方はエラーが起きて動きませんのでご注意ください！
SET !DATASOURCE Address.csv
SET !LOOP 2
SET !DATASOURCE_LINE {{!LOOP}}
URL GOTO=http://demo.imacros.net/Automate/AutoDataEntry
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:fname CONTENT={{!COL1}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:lname CONTENT={{!COL2}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:address CONTENT={{!COL3}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:city CONTENT={{!COL4}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:zip CONTENT={{!COL5}}
注意
最新バージョンのiMacros（無料版）ではSET !DATASOURCEは使えません！
もし使いたい場合はダウングレードする必要があります。

導入の仕方はこちら
iMacrosの初期設定と導入方法iMacrosに必要なFirefox、SmoothCSVの導入方法と初期設定（保存版）【PART.1】

コマンド目次に戻る

BACK

iim
コピー 拡大 
BACK
戻る
ブラウザのBACKボタンと同じで、1つ前のページに戻ります。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
TAG POS=1 TYPE=H2 ATTR=TXT:XPATH【練習用サイト】
BACK
TAG POS=1 TYPE=H2 ATTR=TXT:XPATH【練習用サイト】
BACK

コマンド目次に戻る

CLEAR

iim
コピー 拡大 
CLEAR
キャッシュを削除します。使う場所はログイン作業が含まれるマクロです。

CLEARを入れるとことで、ログアウト状態からスタートさせることができます。
※同じサイトで複数アカウントがある場合は必須です。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
CLEAR
URL GOTO=https://twitter.com/
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:https://twitter.com/sessions ATTR=NAME:session[username_or_email] CONTENT=★ここにメールアドレス★
SET !ENCRYPTION NO
TAG POS=1 TYPE=INPUT:PASSWORD FORM=ACTION:https://twitter.com/sessions ATTR=NAME:session[password] CONTENT=★ここにパスワード★
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:https://twitter.com/sessions ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
CLEAR
URL GOTO=https://blog.seesaa.jp/
TAG POS=1 TYPE=IMG ATTR=SRC:https://blog.seesaa.jp/img/bl/bt_myblog.gif
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:authpost ATTR=ID:email CONTENT=★ここにメールアドレス★
SET !ENCRYPTION NO
TAG POS=1 TYPE=INPUT:PASSWORD FORM=NAME:authpost ATTR=ID:password CONTENT=★ここにパスワード★
TAG POS=1 TYPE=INPUT:SUBMIT FORM=NAME:authpost ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
CLEAR
URL GOTO=https://mail.yahoo.co.jp/promo/
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:login_form ATTR=ID:username CONTENT=★ここにID/電話番号/メールアドレス★
TAG POS=1 TYPE=BUTTON FORM=NAME:login_form ATTR=ID:btnNext
SET !ENCRYPTION NO
TAG POS=1 TYPE=INPUT:PASSWORD FORM=NAME:login_form ATTR=ID:passwd CONTENT=★ここにパスワード★
TAG POS=1 TYPE=BUTTON FORM=NAME:login_form ATTR=ID:btnSubmit
CLEARを使用した実例はこちら
ヤフーメールやGmailに自動ログインマクロ、iMacros：Twitterなどのアカウントに自動ログインする方法【PART.3】

コマンド目次に戻る

REFRESH

iim
コピー 拡大 
REFRESH
更新
ブラウザの更新ボタンと同じでページを更新します。あまり使う機会がないコマンドです
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
REFRESH
REFRESH

コマンド目次に戻る

FILTER

iim
コピー 拡大 
FILTER TYPE=IMAGES STATUS=ON
FILTER TYPE=IMAGES STATUS=OFF
ON 画像表示なし
OFF 画像表示あり
※デフォルト設定
画像ありとなし
YahooのTOPページを画像なし（FILTER TYPE=IMAGES STATUS=ON）にした場合のサンプルです。

サイトの表示速度が遅い場合に、画像を非表示にして読み込みを早くできます。
※ただしCSSで作成されたものは非表示にできません。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
FILTER TYPE=IMAGES STATUS=ON
URL GOTO=https://www.yahoo.co.jp/

コマンド目次に戻る

4. 場所指定

URL GOTO

iim
コピー 拡大 
URL GOTO=URL
URLに入れたサイトにアクセスすることができます。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab.net/

コマンド目次に戻る

TAB

iim
コピー 拡大 
TAB T=番号
TAB CLOSE
TAB OPEN
TAB CLOSEALLOTHERS
T=番号 入れた番号のタブを選択
CLOSE 現在のタブを閉じる
OPEN 新しくタブを開く
CLOSEALLOTHERS 全てのタブ閉じる
※現在使っているタブ以外
iMacrosTAB解説
左から順番に1→2→3…と番号が増えていきます。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
TAB OPEN
TAB T=2
URL GOTO=https://www.google.com/
TAB OPEN
TAB T=3
URL GOTO=https://www.youtube.com/channel/UCIWkro3JEk37xks7u_MhKxg
TAB CLOSEALLOTHERS

コマンド目次に戻る

TAG POS

iim
コピー 拡大 
TAG POS=番号 TYPE=HTML ATTR=サブHTML CONTENT=
TAG POS=番号 TYPE=HTML FORM=フォーム ATTR=サブHTML CONTENT=
POS=番号 何番目の場所を選ぶか決める
例：同じ画像が3つあった場合、上から順番に1→2→3となります
TYPE=HTML どのタイプのHTMLかを指定する
例：A（リンクテキスト）、IMG（画像）、INPUT（入力フォーム）、LI（リスト）、DIVなど
ATTR=サブHTML さらに詳しいHTMLを指定する
例：CLASS、ID、TXTなど
FORM=フォーム フォーム内のHTMLを指定する
例：NAME、ACTIONなど
CONTENT= 文字、数字、コマンドを入れる
例：こんにちは、150、{{!VAR1}}など
※入れる必要がない場合はなくてもOKです

TAG POSを簡単に説明すると、「上から〇〇番目の場所（画像、テキストなど）を選んでね」と指示するためのコマンドです。

上記の表を見ると難しく思えますが、ほとんど自動で書き込んでくれますので覚える必要はありません。

もしも自動でうまくマクロが作れない時のみ自分で作成します。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
TAG POS=1 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/2019/07/imacros-top-160x160.png
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
TAG POS=2 TYPE=INPUT:SEARCH FORM=ID:searchform ATTR=ID:s CONTENT=imacros
TAG POS=2 TYPE=BUTTON FORM=ID:searchform ATTR=ID:searchsubmit
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=111
TAG POS=1 TYPE=TEXTAREA FORM=ID:commentform ATTR=ID:comment CONTENT=こんにちは
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:commentform ATTR=ID:author CONTENT=imacrosくん
TAG POS=1 TYPE=INPUT:URL FORM=ID:commentform ATTR=ID:url CONTENT=https://teilab-sub.net/
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ID:commentform ATTR=ID:submit

コマンド目次に戻る

TAG XPATH

iim
コピー 拡大 
TAG XPATH="XPATH"
TAG XPATHを簡単に言うとTAG POSのレベルアップ版みたいなものです。

「タイトル」「リンク先URL」「CLASS名」「ID名」が変わってもエラーが発生せずその場所を指定してくれます。

例えば、TAG POSで場所を指定できない、時間によって見出しが変化するサイト（ニュース、芸能、スポーツ記事など）のTOPページなどです。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=142
TAG XPATH="//*[@id="entry"]/section/div[1]/ul/li[1]/a"
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
TAG XPATH="//*[@id="topicsfb"]/div[1]/ul[1]/li[2]/a"
TAG XPATHを使用した実例はこちら
iMacros　POSとXPATHの使い方iMacros：TAGコマンドのPOSとXPATHのを使い分ける基準と使い方【PART.9】

コマンド目次に戻る

CLICK

iim
コピー 拡大 
CLICK X=座標 Y=座標
X軸とY軸の図
X軸、Y軸に座標を入れてその場所をクリックすることができます。
※座標はあくまでもイメージです。

前項目のTAG POSやTAG XPATHで場所を指定できなかった場合の回避策で使います。
※Flashページでも利用可

便利なように思えますが、モニターサイズやブラウザの配置など、使う環境によって座標がずれるので高確率でエラーが発生します。

サンプルで使用例を載せていますが、エラーが起きると思います。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=130
CLICK X=621 Y=210
BACK
CLICK X=641 Y=778
CLICKを使用した実例はこちら
iMacrosマウス操作を自動（コマンドCLICK））iMacros：CLICKコマンドでマウス操作を自動化（Firefox専用）【PART.8】
注意
CLICKはFirefox + iMacros8.9.7バージョン以下でのみ使用可能です。

コマンド目次に戻る

ONDIALOG

iim
コピー 拡大 
ONDIALOG POS=番号 BUTTON=種類 CONTENT=入力
POS=番号 何番目にあるダイアログか指定
BUTTON=種類 ボタンの種類はOK、YES、NO、CANSELなど
CONTENT=入力 入力欄が表示された場合に使用
ダイアログ
ボックス（ダイアログ）が表示された時にONDIALOGを使います。クリックした時や、ページを戻ろうとした時などに出てきます。

基本的に全て自動で書き込んでくれますので、手動で作成する機会はほとんどありません。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?page_id=225
ONDIALOG POS=1 BUTTON=OK CONTENT=
TAG POS=1 TYPE=INPUT:BUTTON ATTR=ID:button_01

コマンド目次に戻る

5. データ入力

!DATASOURCE

iim
コピー 拡大 
SET !DATASOURCE ファイル名.csv
SET !DATASOURCE_LINE 行番号
TAG ... CONTENT={{!COL列番号}}
ファイル名.csv どのファイルを使うか指定
※CSVファイル以外は使用不可
LINE 行番号 何行目を使う指定
{{!COL列番号}} 何列目を使う指定
データソースフォルダ
変更していない場合は、Datasourcesフォルダに入っているCSVファイルを使用します。

他のコマンドと違い、複数のコマンドを一緒に使わないといけないため少し初心者の方には難しいです。

ただ大量のデータを自動で入力できるので凄く実用的なコマンドです。

使いこなせれば膨大な時間の短縮が可能になります。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
'※iMacrosダウンロード時に元々入ってるAddress.csvを使っています
'※削除されている方はエラーが起きて動きませんのでご注意ください！
SET !DATASOURCE Address.csv
SET !DATASOURCE_LINE 2
URL GOTO=http://demo.imacros.net/Automate/AutoDataEntry
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:fname CONTENT={{!COL1}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:lname CONTENT={{!COL2}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:address CONTENT={{!COL3}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:city CONTENT={{!COL4}}
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=NAME:zip CONTENT={{!COL5}}
!DATASOURCEを使用した実例はこちら
iMacrosのコマンドdataSource（CSVファイル）を利用して自動入力iMacros：CSVファイル（DATASOURCE）データを利用して自動入力【PART.4】
注意
最新バージョンのiMacros（無料版）ではSET !DATASOURCEは使えません！
もし使いたい場合はダウングレードする必要があります。

導入の仕方はこちら
iMacrosの初期設定と導入方法iMacrosに必要なFirefox、SmoothCSVの導入方法と初期設定（保存版）【PART.1】

コマンド目次に戻る

!VAR

iim
コピー 拡大 
SET !VAR番号 文字列
SET !VAR番号 {{コマンド}}
TAG ... {{!VAR番号}}
!VAR番号 入力した情報を番号に保存
文字列 文字、数字を入れる
例：こんにちは、150など
コマンド コマンドを入れる
例：!URLCURRENT、!EXTRACTなど
{{!VAR番号}} 保存した番号の情報を使う

番号は!VAR0～!VAR9まで使うことができます。
※Google Chromeのみ!VAR1～!VAR3

説明だけでは分かりにくいと思いますので、使用例で一度試してみましょう。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
SET !VAR1 imacros
TAG POS=2 TYPE=INPUT:SEARCH FORM=ID:searchform ATTR=ID:s CONTENT={{!VAR1}}
TAG POS=2 TYPE=BUTTON FORM=ID:searchform ATTR=ID:searchsubmit
iim
コピー 拡大 
VERSION BUILD=8300326 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/
SET !VAR1 {{!URLCURRENT}}
TAB OPEN
TAB T=2
URL GOTO={{!VAR1}}

コマンド目次に戻る

PROMPT

iim
コピー 拡大 
PROMPT "ここに表示したいメッセージをいれます:" !VAR番号
TAG ... CONTENT={{!VAR番号}}
PROMPT 入力するボックスを表示
""（ダブルクォーテーションマーク）で囲われたメッセージを表示
!VAR番号 入力した情報を番号に保存
{{!VAR番号}} 保存した番号の情報を使う
画像認証　imacros
PROMPTを使った場合に出てくるボックスの例です。

特定の場所だけ手動入力したい場合に使います。

例えば、画像認証やブログにコメントする時などです。

その他には、入力欄を出さずにメッセージだけを表示させることも可能です。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=100
PROMPT "画像認証を行ってください:" !VAR1
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=100#wpcf7-f97-p100-o1 ATTR=NAME:captcha CONTENT={{!VAR1}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=100#wpcf7-f97-p100-o1 ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=111
PROMPT "コメントを入力してください:" !VAR1
TAG POS=1 TYPE=TEXTAREA FORM=ID:commentform ATTR=ID:comment CONTENT={{!VAR1}}
PROMPT "名前を入力してください:" !VAR2
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:commentform ATTR=ID:author CONTENT={{!VAR2}}
PROMPT "メールアドレスを入力してください:" !VAR3
TAG POS=1 TYPE=INPUT:EMAIL FORM=ID:commentform ATTR=ID:email CONTENT={{!VAR3}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ID:commentform ATTR=ID:submit
PROMPTを使用した実例はこちら
iMacros：PROMPTと!VARで特定の場所を手動入力にする【PART.6】

コマンド目次に戻る

EVAL

iim
コピー 拡大 
SET !VAR番号 EVAL("JavaScript")
TAG ... CONTENT={{!VAR番号}}
EVALはiMacros内でJavaScriptを使う時に使用します。

それと基本的に前の項目の!VARコマンドとセットです。

使い方は色々ありますが、文字や数値をランダムに入力したりできます。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=122
SET !VAR1 EVAL("var randomNumber=Math.floor(Math.random()*10+ 1); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=122#wpcf7-f123-p122-o1 ATTR=NAME:text CONTENT={{!VAR1}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=122#wpcf7-f123-p122-o1 ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=109
SET !VAR1 EVAL("var randomNumber=Math.floor(Math.random()*3+ 2019); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=ID:year CONTENT={{!VAR1}}
SET !VAR2 EVAL("var randomNumber=Math.floor(Math.random()*12+ 1); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=ID:month CONTENT={{!VAR2}}
SET !VAR3 EVAL("var randomNumber=Math.floor(Math.random()*28+ 1); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=ID:day CONTENT={{!VAR3}}
SET !VAR4 EVAL("var randomNumber=Math.floor(Math.random()*23+ 1); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=ID:hour CONTENT={{!VAR4}}
SET !VAR5 EVAL("var randomNumber=Math.floor(Math.random()*59+ 1); randomNumber;")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=ID:minutes CONTENT={{!VAR5}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=109#wpcf7-f108-p109-o1 ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=126
SET !VAR1 EVAL("var letters = ['a','b','c','d','e','f','g','h','i','j','k','l','m','n','o','p','q','r','s','t','u','w','x','y','z']; var string = ''; for(var i = 0; i < 10; i++){string += letters[parseInt(Math.random() * 25)]}; string")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=126#wpcf7-f123-p126-o1 ATTR=NAME:text CONTENT={{!VAR1}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=126#wpcf7-f123-p126-o1 ATTR=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=126
SET !VAR1 EVAL("var randomNumber=Math.floor(Math.random()*10+ 1); randomNumber;")
SET !VAR2 EVAL("var letters = ['a','b','c','d','e','f','g','h','i','j','k','l','m','n','o','p','q','r','s','t','u','w','x','y','z']; var string = ''; for(var i = 0; i < 10; i++){string += letters[parseInt(Math.random() * 25)]}; string")
TAG POS=1 TYPE=INPUT:TEXT FORM=ACTION:/?p=126#wpcf7-f123-p126-o1 ATTR=NAME:text CONTENT={{!VAR1}}{{!VAR2}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/?p=126#wpcf7-f123-p126-o1 ATTR=*
EVALを使用した実例はこちら
EVAL アイキャッチiMacros：EVALでランダムに数値や文字を入力する方法【PART.7】

コマンド目次に戻る

!CLIPBOARD

iim
コピー 拡大 
EXTRACT=TXT
SET !CLIPBOARD {{!EXTRACT}}
{{!CLIPBOARD}}
クリップボード
!CLIPBOARDはクリップボードにコピーしたりペースト（貼り付け）できるコマンドです。
  • コピー（抜き出す）＝EXTRACT=TXT
  • クリップボード（保存）＝SET !CLIPBOARD {{!EXTRACT}}
  • ペースト（貼り付け）＝{{!CLIPBOARD}}

※EXTRACT=TXT以外でも使えます。詳しくはEXTRACT項目でご確認して頂ければと思います。

例えば、サイトの文字をクリップボードに保存して、そのデータで検索する使い方ができます。

説明を見るとややこしく感じますが、実際にやっていることはコピー＆ペーストを自動でしているだけです。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
TAG POS=1 TYPE=A ATTR=ID:js-cbysC1 EXTRACT=TXT
SET !CLIPBOARD {{!EXTRACT}}
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:sf1 ATTR=ID:srchtxt CONTENT={{!CLIPBOARD}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=NAME:sf1 ATTR=ID:srchbtn
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://search.yahoo.co.jp/realtime
TAG POS=1 TYPE=A ATTR=HREF:http://search.yahoo.co.jp/r/top/*=rts_top_bzmod EXTRACT=TXT
SET !CLIPBOARD {{!EXTRACT}}
URL GOTO=https://yahoo.co.jp/
TAG POS=1 TYPE=INPUT:TEXT FORM=NAME:sf1 ATTR=ID:srchtxt CONTENT={{!CLIPBOARD}}
TAG POS=1 TYPE=INPUT:SUBMIT FORM=NAME:sf1 ATTR=ID:srchbtn

コマンド目次に戻る

!NOW

iim
コピー 拡大 
!NOW:(コード)
yyyy 年を4桁（2019~9999）で表示
yy 年を2桁（00~99）で表示
mm 月を2桁（01-12）で表示
dd 日を2桁（01-31）で表示
hh 時間を2桁（00-23）で表示
nn 分を2桁（00-59）で表示
ss 秒を2桁の（00-59）で表示

現在の年、月、日などを入力したい時に使います。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=111
TAG POS=1 TYPE=TEXTAREA FORM=ID:commentform ATTR=ID:comment* CONTENT={{!NOW:yyyy年mm月dd日<SP>hh時<SP>nn分<SP>ss秒}}
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=111
TAG POS=1 TYPE=TEXTAREA FORM=ID:commentform ATTR=ID:comment* CONTENT={{!NOW:yyyy-mm-dd<SP>hh-nn-ss}}
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab-sub.net/?p=111
TAG POS=1 TYPE=TEXTAREA FORM=ID:commentform ATTR=ID:comment* CONTENT={{!NOW:mm-dd}}

コマンド目次に戻る

6. データ抜き出し

EXTRACT

iim
コピー 拡大 
TAG ... EXTRACT=TXT
TAG ... EXTRACT=HREF
TAG ... EXTRACT=HTM
TAG ... EXTRACT=ALT
TAG ... EXTRACT=TITLE
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
TXT 文字列を抜き出す
HREF URLを抜き出す
HTM HTMLを抜き出す
ALT ALTを抜き出す
TITLE TITLEを抜き出す
ダウンロードフォルダ
抜き出したデータは「Downloads」に保存されます。

EXTRACTは使用頻度が非常に高いコマンドです。

指定した場所のデータ（文字、URL、HTMLなど）を簡単に抜き出す事ができます。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=31
TAG POS=1 TYPE=H2 ATTR=* EXTRACT=TXT
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=TXT
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=39
TAG POS=1 TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/* EXTRACT=HREF
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=39
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=HTM
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=39
TAG POS=1 TYPE=H2 ATTR=* EXTRACT=TXT
TAG POS=1 TYPE=A ATTR=CLASS:url&&HREF:https://teilab-sub.net/* EXTRACT=HREF
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=HTM
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
EXTRACTを使用した実例はこちら
EXTRACTを使用して特定の文字、画像やHTMLを抜き出すiMacros：EXTRACTで文字、HTML、画像を抜き出す【PART.5】

コマンド目次に戻る

!EXTRACT_TEST_POPUP

iim
コピー 拡大 
SET !EXTRACT_TEST_POPUP YES
SET !EXTRACT_TEST_POPUP NO
YES ポップアップで抜き出し箇所を表示
※デフォルト設定
NO ポップアップ抜き出し箇所を非表示（ブロック）
SET !EXTRACT_TEST_POPUP NO
前項目のEXTRACTコマンドを使うと、抜き出し箇所を表示する設定なっています。
※このボックスはポップアップと言います

ポップアップが表示されると、毎回マクロが止まってしまうので自動化している意味がなくなります。

SET !EXTRACT_TEST_POPUP NOを入れるとポップアップを非表示できます。

EXTRACTコマンドを使うときは、必ず入れておきましょう。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
SET !EXTRACT_TEST_POPUP NO
URL GOTO=https://teilab-sub.net/?p=31
TAG POS=1 TYPE=H2 ATTR=* EXTRACT=TXT
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=TXT
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*

コマンド目次に戻る

NULL

iim
コピー 拡大 
SET !EXTRACT NULL
imacrosコマンド NULL
EXTRACTで抜き出したデータを破棄する場合にNULLコマンドを使います。
※NULLの意味は何もデータがないです。

例えば、マクロの途中で抜き出したデータを一時的に使うけど、CSVファイルに保存する必要がないので場合に使ったりします。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
SET !EXTRACT_TEST_POPUP NO
URL GOTO=https://teilab-sub.net/?p=31
TAG POS=1 TYPE=H2 ATTR=* EXTRACT=TXT
SET !EXTRACT NULL
TAG POS=1 TYPE=DIV ATTR=CLASS:sng-box<SP>box2 EXTRACT=TXT
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
補足
意味のないマクロですが、入れる位置だけ覚えて頂ければと思います。

コマンド目次に戻る

SAVEITEM

iim
コピー 拡大 
TAG ... CONTENT=EVENT:SAVEITEM
ダウンロードフォルダ
抜き出した画像データは「Downloads」に保存されます。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/?p=59
TAG POS=1 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/*.png CONTENT=EVENT:SAVEITEM
TAG POS=2 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/*.png CONTENT=EVENT:SAVEITEM
TAG POS=3 TYPE=IMG ATTR=SRC:https://teilab-sub.net/wp-content/uploads/*.png CONTENT=EVENT:SAVEITEM
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://pixabay.com/ja/images/search/%E7%8C%AB/
TAG POS=1 TYPE=IMG ATTR=SRC:https://cdn.pixabay.com/photo/*.jpg CONTENT=EVENT:SAVEITEM
TAG POS=2 TYPE=IMG ATTR=SRC:https://cdn.pixabay.com/photo/*.jpg CONTENT=EVENT:SAVEITEM
TAG POS=3 TYPE=IMG ATTR=SRC:https://cdn.pixabay.com/photo/*.jpg CONTENT=EVENT:SAVEITEM
TAG POS=4 TYPE=IMG ATTR=SRC:https://cdn.pixabay.com/photo/*.jpg CONTENT=EVENT:SAVEITEM
TAG POS=5 TYPE=IMG ATTR=SRC:https://cdn.pixabay.com/photo/*.jpg CONTENT=EVENT:SAVEITEM
SAVEITEMを使用した実例はこちら
EXTRACTを使用して特定の文字、画像やHTMLを抜き出すiMacros：EXTRACTで文字、HTML、画像を抜き出す【PART.5】

コマンド目次に戻る

SAVE

iim
コピー 拡大 
SAVEAS TYPE=CPL FOLDER=* FILE=*
SAVEAS TYPE=TXT FOLDER=* FILE=*
SAVEAS TYPE=HTM FOLDER=* FILE=*
SAVEAS TYPE=PNG FOLDER=* FILE=*
SAVEAS TYPE=JPEG FOLDER=* FILE=*
TYPE= 保存する種類を指定
CPL ページの中身を全て保存
TXT ページ全体のテキストを保存
※データの閲覧はテキストエディター（メモ帳、Terapadなど）で開く必要があります。
HTM ページ全体のHTMLを保存
PNG ページ全体をスクリーンショットで保存
JPEG ページ全体をスクリーンショットで保存
ダウンロードフォルダ
抜き出したデータは「Downloads」に保存されます。

SAVESコマンドは、ページ全体のデータ（テキスト、HTML、画像など）を一括で保存したい場合に使います。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
SAVEAS TYPE=CPL FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
SAVEAS TYPE=TXT FOLDER=* FILE=*
注意
保存したデータはCOファイルのため、中身の確認はテキストエディター（メモ帳、Terapadなど）で開く必要があります。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
SAVEAS TYPE=HTM FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
SAVEAS TYPE=PNG FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.yahoo.co.jp/
SAVEAS TYPE=JPEG FOLDER=* FILE=*

コマンド目次に戻る

!URLCURRENT

iim
コピー 拡大 
ADD !EXTRACT {{!URLCURRENT}}
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
現在のURLを抜き出す
現在開いているページのURLを抜き出します。
※URLCURRENTの訳は現在のURLです。
ダウンロードフォルダ
抜き出したデータは「Downloads」に保存されます。
  • 抜き出す＝ADD !EXTRACT {{!URLCURRENT}}
  • 保存場所を指定＝SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
URL GOTO=https://teilab.net/
ADD !EXTRACT {{!URLCURRENT}}
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab.net/
ADD !EXTRACT {{!URLCURRENT}}
URL GOTO=https://www.yahoo.co.jp/
ADD !EXTRACT {{!URLCURRENT}}
SAVEAS TYPE=EXTRACT FOLDER=* FILE=*

コマンド目次に戻る

ONDOWNLOAD

iim
コピー 拡大 
ONDOWNLOAD FOLDER=* FILE=* WAIT=YES
ONDOWNLOAD FOLDER=* FILE=* WAIT=NO
FOLDER= データを保存するフォルダを指定
FILE= データのファイル名を指定
WAIT= YES：ダウンロードが完了するまで待つ
NO：ダウンロード完了まで待たず次のコマンドを実行する
※時間短縮したい方はNOがおすすめ
ダウンロード
ONDOWNLOADは、データ（ソフト、PDF、Excelなど）をダウンロードする時に使うコマンドです。
ダウンロードフォルダ
抜き出したデータは「Downloads」に保存されます。

ダウンロードリンクをクリックして、ダイアログ（確認メッセージ）が出るのが遅い場合、エラーが起きる可能性があります。

そんな時はWAITコマンド（WAIT SECONDS=10）を入れて10秒ほど待ち時間を作ります。

待ち時間は、長めにしておいた方がエラーが起きにくいです。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://www.google.co.jp/chrome/
TAG POS=1 TYPE=BUTTON ATTR=ID:js-download-hero
ONDOWNLOAD FOLDER=* FILE=+_{{!NOW:yyyymmdd_hhnnss}} WAIT=YES
WAIT SECONDS=10
TAG POS=1 TYPE=BUTTON ATTR=ID:js-accept-install
補足
ONDOWNLOADコマンドは!NOWコマンドが自動で付与されます。
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
TAB T=1
SET !REPLAYSPEED MEDIUM
URL GOTO=https://teilab-sub.net/?page_id=266
ONDOWNLOAD FOLDER=* FILE=+_{{!NOW:yyyymmdd_hhnnss}} WAIT=YES
TAG POS=1 TYPE=A ATTR=TXT:こちらクリック
補足
ONDOWNLOADコマンドは!NOWコマンドが自動で付与されます。

コマンド目次に戻る

7. その他

VERSION

iim
コピー 拡大 
VERSION BUILD=バージョン情報 RECORDER=ブラウザ名
手紙の書き出しのようなものなので気にしなくて大丈夫です。

それと自動で書き込まれますので、手動で作成することはありません。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
iim
コピー 拡大 
VERSION BUILD=844 RECORDER=CR

コマンド目次に戻る

'(コメントアウト)

iim
コピー 拡大 
'
使い方は「注意書きやメモ」や「特定のマクロを読み込ませない」などがあります。

それと半角アポストロフィー（'）しか使用できませんので注意しましょう。

正しくコメントアウトになっている場合は、その箇所が緑色に表示されます。

iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
'速度調節
SET !REPLAYSPEED MEDIUM
TAB T=1
'URLにアクセス
URL GOTO=https://teilab-sub.net/
iim
コピー 拡大 
VERSION BUILD=8970419 RECORDER=FX
'↓エラーが起きる場合に使う
'SET !REPLAYSPEED MEDIUM
TAB T=1
URL GOTO=https://teilab-sub.net/

コマンド目次に戻る

*(ワイルドカード)

iim
コピー 拡大 
*
ワイルドカードをトランプで例えると、ジョーカーのようにどんなものにも置き変わることができる性質を持っています。

例えば以下のようなURLがあったとします。

  • https://teilab-sub.net/10
  • https://teilab-sub.net/22
  • https://teilab-sub.net/test
  • https://teilab-sub.net/sample-01
  • https://teilab-sub.net/sample-0502

https://teilab-sub.net/の後ろのURLが全てバラバラになっています。

この場合https://teilab-sub.net/*にすることで全てURLに対応することができます。

特に抜き出しするEXTRACTコマンドで使う機会が出てきます。

ワイルドカードの詳しい使い方はこちら
EXTRACTを使用して特定の文字、画像やHTMLを抜き出すiMacros：EXTRACTで文字、HTML、画像を抜き出す【PART.5】
補足
*(ワイルドカード)の使用箇所は「②URL（HREF）編」「④画像（SAVEITEM）編」「楽天ランキング編」です。使う場所の判断は、上記リンク先の参考例をもとにご自分で作成すると理解しやすいです。

コマンド目次に戻る

全てのコマンド

ほとんど使わないものが多いのですが、このページに載せていないコマンドが他にもあります。

確認してみたい方はこちら
参考 コマンド一覧（英語）iMacros wiki（公式）

注意
全て英語で書かれたページなので、ある程度iMacrosを使いこなせている方でないと理解しにくい可能性があります。

8. 補足説明

エラーを減らす方法

一番多いエラーの原因は「コピペミス」と「空白や番号を全角にする」の2点です。

この2点だけ注意しておけば、エラーの確率が大幅に減りますので覚えておきましょう。

補足
iMacrosに限らずプログラム言語は全て半角です。

定形済み変数とは？

!（ビックリマーク）が最初に付いているものを定型済み変数と言います。

  • 変数：学生時代に数学で出てきたX（エックス）の役割をします。
  • 定型済み：入るものが決まっている。

定型済み変数とは、Xの中に何が入るか決まっているものをそう呼んでいます。

ノーノちゃん

数学苦手だから全くわからない(´；ω；`)ｳｩｩ
そんなのがあるんだぁ…ぐらいでOKです。覚える必要はありませんのでご安心を(^^♪

テイくん

9. まとめ

このページのコマンド一覧は、iMacrosを使う時に参考にして頂ければと思います。

よく使うコマンドは、クリップNOTE（無料）や一覧表にして保存しておいた方が時間短縮できます。

筆者はクリップNOTEを使っています。

まとめ
  • 必要な部分をコピペして使えばOK
  • よく使うコマンドを保存しておく
  • サンプルマクロを活用しよう！

基礎から勉強したい方はこちら（合計11ページ）
ブラウザ上の作業を全て自動化できるiMacros ブラウザ上の作業を全て自動化できるiMacrosとは？【PART.0】

前の記事

ニコンの新型ミラーレス Z50【体験レビュー】
ニコンの新型ミラーレス Z50【体験レビュー】

次の記事

【超初心者向け】わかりやすいミラーレス一眼の選び方
【超初心者向け】わかりやすいミラーレス一眼の選び方